AVEVA™ Unified Engineering

Methods of the PcfExporter

Save PDF

Methods of the PcfExporter

Save PDF

Last UpdatedMar 04, 2026
2 minute read

Exporting of PCF data is also supported from the PML level, an element that interacts with exporting PCF data is identified as PcfExporter. A list of methods that are available for this elements are displayed in the PcfExporter list of methods table.

LP	Method Call	Return	Description
1	AddMembers()	-	Adds all pipelines from the current element to the exporter table
2	AddPipeline()	-	Adds a pipeline of the current element to the exporter table
3	Export()	-	Exports PCF data
4	ExportImpliedBolts()	BOOLEAN	Gets ExportImpliedBolts flag
5	ExportImpliedBolts (BOOLEAN)	-	Sets ExportImpliedBolts flag
6	ExportImpliedWelds()	BOOLEAN	Gets ExportedImpliedWelds flag
7	ExportImpliedWelds (BOOLEAN)	-	Sets ExportedImpliedWelds flag
8	ExprBoltedConnection()	STRING	Gets expression indicating bolted connections
9	ExprBoltedConnection (STRING)	-	Sets expression indicating bolted connections
10	ExprWeldedConnection()	STRING	Gets expression indicating welded connections
11	ExprWeldedConnection (STRING)	-	Sets expression indicating welded connections
12	GetPipelines()	ARRAY	Gets all pipelines from exporter table as array records: [1] IsSelected [2] Pipeline [3] OutputFolder
13	LoadSettings(STRING)	-	Loads settings from *.xpe file
14	ModifyPipeline(REAL, BOOLEAN, STRING)	BOOLEAN	Modifies selected record in the exporter table
15	OutputFolder()	STRING	Gets value of root output folder
16	OutputFolder(STRING)	-	Sets value of root output folder
17	OverwriteFiles()	BOOLEAN	Gets flag whether to over write existing files
18	OverwriteFiles (BOOLEAN)	-	Sets flag whether to over write existing files
19	RemovePipeline(REAL)	BOOLEAN	Removes selected record from the exporter table
20	RemovePipelines()	-	Removes selected record from the exporter table
21	SaveSettings(STRING)	-	Saves settings to *.xpe file

Example of PML Code

-- Initiate exporter

!obj = object PcfExporter()

!obj.RemovePipelines()

!obj.OutputFolder('C:\Temp\!PCF-PML')

!obj.OverwriteFiles(true)

!obj.ExportImpliedBolts(true)

!obj.ExportImpliedWelds(true)

!obj.ExprBoltedConnection('F.*|L.*')

!obj.ExprWeldedConnection('SW.|BW.')

-- Add all pipelines

VAR !PIPES EVAL (NAME) FOR ALL PIPE WITH ISNAMED EQ TRUE AND BADREF(SITE) EQ FALSE

!PIPES.SORT()

DO !X VALUES !PIPES

$!X

!obj.AddPipeline()

ENDDO

-- Modify records

!RECORDS = !obj.GetPipelines()

!SIZE = !RECORDS.SIZE()

DO !IDX FROM 1 TO !SIZE BY 1

!NAME = !RECORDS[!IDX][2]

!PSPE = PSPE OF $!NAME

IF NOT(BADREF(!PSPE)) AND !PSPE.ISNAMED THEN

!SEL = !RECORDS[!IDX][1]

!obj.ModifyPipeline(!IDX, !SEL, !PSPE.NAMN)

ENDIF

ENDDO

-- Get common part of root folder

!folder = !obj.OutputFolder()

-- Save settings 1

!obj.OutputFolder(!folder + '\All')

!obj.ExportImpliedBolts(true)

!obj.ExportImpliedWelds(true)

!obj.SaveSettings('C\TEMP\!PCF-PML\Test-All.xpe')

-- Save settings 2

!obj.OutputFolder(!folder + '\Bolt')

!obj.ExportImpliedBolts(true)

!obj.ExportImpliedWelds(false)

!obj.SaveSettings('C\TEMP\!PCF-PML\Test-Bolt.xpe')

-- Save settings 3

!obj.OutputFolder(!folder + '\Weld')

!obj.ExportImpliedBolts(false)

!obj.ExportImpliedWelds(true)

!obj.SaveSettings('C\TEMP\!PCF-PML\Test-Weld.xpe')

-- Save settings 4

!obj.OutputFolder(!folder + '\None')

!obj.ExportImpliedBolts(false)

!obj.ExportImpliedWelds(false)

!obj.SaveSettings('C\TEMP\!PCF-PML\Test-None.xpe')

-- Export

!obj.LoadSettings('C\TEMP\!PCF-PML\Test-All.xpe')

!obj.Export()

!obj.LoadSettings('C\TEMP\!PCF-PML\Test-Bolt.xpe')

!obj.Export()

!obj.LoadSettings('C\TEMP\!PCF-PML\Test-Weld.xpe')

!obj.Export()

!obj.LoadSettings('C\TEMP\!PCF-PML\Test-None.xpe')

!obj.Export()

AVEVA™ Unified Engineering