Syntactical Description of Robot Interface Output

< >

Delimits symbols

::=

Denotes that the symbol to the left is constituted by the expression to the right.

|

Means 'or'.

{ }

The symbol(s) inside the curly brackets may be repeated zero or more times.

[ ]

The symbol(s) inside the brackets may occur zero or one time.

<atx-file> ::=

{<object>}

<object> ::=

<panel>|

<assembly>|

<curve>|

<longitudinal>|

<transversal>

<panel> ::=

<start-of-panel>

<date-rec>

<name-rec>

<panel-contents>

{<local-transf>}

<end-of-panel>

<local-transf> ::=

<thickness>

<assembly> ::=

<start-of-assembly>

<asse-name>

<assemblytransf>

{<panel-contents>}

<end-of-assembly>

curve> ::=

<start-of-curve>

<date-rec>

<name-rec>

<curve-contents>

<end-of-curve>

<longitudinal> ::=

<start-of-longitudinal>

<date-rec>

<name-rec>

[<layer>]

<longitudinal-part>

<end-of-longitudinal>

<transversal> ::=

<start-of-transversal>

<date-rec>

<name-rec>

[<layer>]

<transversal-part>

<end-of-transversal>

<panel-contents> ::=

[<layer>]

{

<plate-or-panel>

[<layer>]

{<panel-hole>}

[layer]

{<panel-cutout-or-notch>}

}

[<layer>]

{

<stiffener>

[<layer>]

{<sub-volume}

}

[<layer>]

{

<flange>

[<layer>]

{<sub-volume>}

}

[<layer>]

{

<pillar>

[<layer>]

{<sub-volume>}

}

[<layer>]

{

<bracket-plate>

[<layer>]

{

<stiffener>

[<layer>]

{<sub-volume>}

}

[<layer>]

{

<flange>

[<layer>]

{<sub-volume>}

}

}

[<layer>]

{<clip>}

[<layer>]

{<doubling>}

<assemblytransf> ::=

232 <origin>

232 <uvec>

232 <wvec>

<curve-contents> ::=

[<layer>]

<contour>

<longitudinal-part> ::=

<start-of-longitudinal-part>

<name-rec>

<prod-inf>

<volume>

<end-of-longitudinal-part>

<transversal-part> ::=

<start-of-transversal-part>

<name-rec>

<prod-inf>

<volume>

<end-of-transversal-part>

<plate-or-panel> ::=

<plate-part>|

<panel-part>

<plate-part> ::=

<start-of-plate>

<volid>

<part>

<end-of-plate>

<panel-part> ::=

<start-of-panel-plate>

<volid>

<part>

<end-of-panel-plate>

<stiffener> ::=

<start-of-stiffener>

<volid>

<proftypandparam>

<stif-part>

<end-of-stiffener>

<flange> ::=

<start-of-flange>

<volid>

<proftypandparam>

<part>

<end-of-flange>

<pillar> ::=

<start-of-pillar>

<volid>

<proftypandparam>

<part>

<end-of-pillar>

<bracket-plate> :==

<start-of-bracket-plate>

<volid>

<part>

<end-of-bracket-plate>

<bracket> ::=

<start-of-bracket>

<volid>

<part>

<end-of-bracket>

<doubling> ::=

<start-of doubling>

<volid>

<part>

<end-of-doubling>

<clip> ::=

<start-of-clip>

<volid>

<part>

<macro-id>

<end-of-clip>

<volid> ::=

[<seq-no> <triname>]

<part> ::=

<prod-inf>

<volume>

<stif-part> ::=

<prod-inf>

<stif-rep>

<volume>

<subvolume> ::=

<endcut>|

<cutout>|

<hole>|

<notch>

<prod-inf> ::=

[asse_name>]

[<asslev1>]

[<asslev2>]

[<asslev3>]

[<asslev4>]

[<surftreat>]

[<destin>]

[<posno>]

[<steelqual>]

<endcut> ::=

<start-of-endcut>

<endcut-contents>

<end-of-endcut>

<cutout> ::=

<start-of-cutout>

<cutout-contents>

<end-of-cutout>

<hole> ::=

<start-of-hole>

<hole-contents>

<end-of-hole>

<notch> ::=

<start-of-notch>

<notch-contents>

<end-of-notch>

<panel-hole> ::=

<start-of-hole>

<panel-hole-contents>

<end-of-hole>

<panel-cutout-or-notch> ::=

<panel-cutout>|

<panel-notch>

<panel-cutout> ::=

<start-of-cutout>

<panel-cutout-contents>

<end-of-cutout>

<panel-notch> ::=

<start-of-notch>

<panel-notch-contents>

<end-of-notch>

<endcut-contents> ::=

<endcut-type>

<sub-seq>

<volume>

<cutout-contents> ::=

<cutout-type>

<sub-seq>

<volume>

<hole-contents> ::=

<hole-type>

<sub-seq>

<volume>

<panel-hole-contents> ::=

<name-rec>

<sub-seq>

<volume>

<notch-contents> ::=

<notch-type>

<sub-seq>

<volume>

<panel-cutout-contents> ::=

<cutout-type>

<cutout-point>

<panel-notch-contents> ::=

<notch-type>

<notch-point>

<proftypandparam> ::=

200 <integer>

{<real>}

<asslev1> ::=

201 <string>

<asslev2> ::=

202 <string>

<asslev3> ::=

203 <string>

<asslev4> ::=

204 <string>

<surftreat> ::=

205 <string>

<destin> ::=

206 <string>

<posno> ::=

207 <integer>

<steelqual> ::=

208 <integer>

<endcut-type> ::=

209 <integer>

{<real>}

<cutout-type> ::=

210 <integer>

<notch-type> ::=

211 <string>

<hole-type> ::=

212 <string>

<sub-seq> ::=

213 <integer> <integer> [<integer>]

<seq-no> ::=

214 <integer>

<stif-rep> ::=

216 <integer>

<cutout-point> ::=

217 <point>

<notch-point> ::=

217 <point>

<macro-id> ::=

218 <string>

<volume> ::=

<contour>

<thickness>

<contour> ::=

<startpoint>

<segment>

{<segment>}

<thickness> ::=

240 <point>

241 <uvec>

242 <wvec>

<origin> ::=

<point>

<uvec> ::=

<point>

<wvec> ::=

<point>

<vec-1> ::=

<point>

<vec-2> ::=

<point>

<startpoint> ::=

15 <point>

<segment> ::=

16 <point> <point>

<point> ::=

<real> <real> <real>

<ampl> :==

<real> <real> <real>

<date-rec> ::=

230 <date>

<name-rec> ::=

2 <name>

<asse-name> ::=

231 <name>

triname> ::=

215 <name>

<start-of-panel> ::=

1701

<end-of-panel> ::=

99

<start-of-assembly> ::=

1735

<end-of-assembly> ::=

99

<start-of-curve> ::=

1741

<end-of-curve> ::=

99

<start-of-longitudinal> ::=

71731

<end-of-longitudinal> ::=

70731

<start-of-longitudinal-part> ::=

71732

<end-of-longitudinal-part> ::=

70732

<start-of-transversal> ::=

71733

<end-of-transversal> ::=

70733

<start-of-transversal-part> ::=

71734

<end-of-transversal-part> ::=

70734

<start-of-plate> ::=

71707

<start-of-doubling> ::=

71708

<start-of-panel-plate> ::=

71702

<start-of-stiffener> ::=

71704

<start-of-flange> ::=

71705

<start-of-pillar> ::=

71706

<start-of-bracket-plate> :==

71722

<end-of-plate> ::=

71707

<end-of-doubling> ::=

70708

<end-of-panel-plate> ::=

70702

<end-of-stiffener> ::=

70704

<end-of-flange> ::=

70705

<end-of-pillar> ::=

70706

<end-of-bracket-plate> ::=

70722

<start-of-clip>::=

71724

<end-of-clip>::=

70724

<start-of-endcut> ::=

71750

<end-of-endcut> ::=

70750

<start-of-cutout> ::=

71751

<end-of-cutout> ::=

70751

<start-of-notch> ::=

71752

<end-of-notch> ::=

70752

<start-of-hole> ::=

71703

<end-of-hole> ::=

70703

<layer> ::=

9 <integer>

<date> ::=

YYYY-MM-DD HH:MM:SS:CC

<name> ::=

<letter>{<character>}

<string> ::=

<character>{<character>}